% This is a first draft of how left parentheses might look in the new CM fonts.
c=1;

def makeit=
font_setup;
"Left parenthesis";
beginchar("(", fixwidth[7,9]*u#, hheight#+border#, hheight#+border#-2axis#);
italcorr (hheight#+border#)*slant-.5u#;
pickup tinypen;
penpos1(hair-tiny,0); penpos3(hair-tiny,0);
penpos2(.75[thin,thick]-tiny,0);
rt x1r = rt x3r = w-fixwidth[u,9/6u]; lft x2l = x1-4u;
% rounding not included yet; I'm thinking of doing something like
% top rt ↑z1r = round ↑(w-u,h).
top y1=h; y2=.5[y1,y3]=axis;
filldraw z1l{curl c}..z2l..{curl c}z3l--
	  z3r{curl c}..z2r..{curl c}z1r--cycle;
penlabels(1,2,3); endchar;
enddef;

def font_setup=
define_pixels(u,tiny,axis,hheight,border);
define_blacker_pixels(hair,thin,thick,rulethickness);
pickup if tiny<.5: nullpen else: pencircle scaled tiny fi;
tinypen:=savepen;
currenttransform:=identity slanted slant yscaled aspect_ratio;
enddef;

"Roman"; charfam:=0;
u#:=20/36pt#;
tiny#:=0;
axis#:=90/36pt#;
hheight#:=250/36pt#;
border#:=20/36pt#;
hair#:=8/36pt#;
thin#:=9/36pt#;
thick#:=25/36pt#;
fixwidth:=0;
slant:=0;
rulethickness:=.4pt#;
makeit;
"Bold Extended"; charfam:=1;
u#:=23/36pt#;
tiny#:=0;
axis#:=90/36pt#;
hheight#:=250/36pt#;
border#:=20/36pt#;
hair#:=13/36pt#;
thin#:=17/36pt#;
thick#:=41/36pt#;
fixwidth:=0;
slant:=0;
makeit;
"Typewriter"; charfam:=2;
u#:=21/36pt#;
tiny#:=22/36pt#;
axis#:=110/36pt#;
hheight#:=220/36pt#;
border#:=30/36pt#;
hair#:=22/36pt#;
thin#:=25/36pt#;
thick#:=25/36pt#;
fixwidth:=1;
slant:=0;
makeit;
"Italic"; charfam:=3;
u#:=18.4/36pt#;
tiny#:=8/36;
axis#:=90/36pt#;
hheight#:=250/36pt#;
border#:=20/36pt#;
hair#:=8/36pt#;
thin#:=11/36pt#;
thick#:=23/36pt#;
fixwidth:=0;
slant:=.25;
makeit;
"Sans-serif Demibold Condensed"; charfam:=4;
u#:=19/36pt#;
tiny#:=8/36pt#;
axis#:=90/36pt#;
hheight#:=250/36pt#;
border#:=20/36pt#;
hair#:=23/36pt#;
thin#:=40/36pt#;
thick#:=40/36pt#;
fixwidth:=0;
slant:=0;
makeit;
end